TeraTerm Support Forums • View topic - Tera Term 4.64

dpena · **Joined:** Thu Jul 09, 2009 11:14 am **Posts:** 26

Hi,

I have the following apps installed

Tera Term 4.64
LogMeTT 2.9.7
TTLEditor 1.1.5

and started using fileopen and have come to question whether or not these commands work??

Here are the details behind my laptop:

Quote:

------------------
System Information
------------------
Time of this report: 1/20/2010, 19:00:57
Operating System: Windows XP Professional (5.1, Build 2600) Service Pack 3 (2600.xpsp_sp3_gdr.090804-1435)
Language: English (Regional Setting: English)
System Manufacturer: LENOVO
System Model: 7665D89
BIOS: Ver 1.00PARTTBLx
Processor: Intel(R) Core(TM)2 Duo CPU T7300 @ 2.00GHz (2 CPUs)
Memory: 2014MB RAM
Page File: 1194MB used, 2711MB available
Windows Dir: C:\WINDOWS
DirectX Version: DirectX 9.0c (4.09.0000.0904)

I went ahead and ran the tera term sample code to keep it simple but it appears the "text.txt" file never is opened and "filereadln" never populates the variable "line".

Here is the code I'm using to test the "fileopen" function:

Select all

 
tmp01 = ''
 
; Open a file.
fileopen fhandle 'test.txt' 0
 
messagebox fhandle 'USER PROMPT 01'
 
:loop
 
; Read a line from the file.
filereadln fhandle line
 
messagebox line 'USER PROMPT 02'
 
sprintf2 tmp01 'result = %d' result
messagebox tmp01 'USER PROMPT 03'
 
if result = 1 goto fclose
 
; Display the line.
messagebox line 'test.txt'
 
; Repeat until the end of the file.
goto loop
 
:fclose
; Close the file.
fileclose fhandle
 
end
 

Here is the test.txt file content

Select all

 
It seems
fileopen will not
open text files specified
very strange
 

Has anyone experienced this issue with the versions outlined above?

boris · **Posted:** Wed Jan 20, 2010 11:19 pm

I tested your code. It worked fine when I added full path to the file name.
Another option would be to change the default directory with setdir before opening the file.

dpena · **Joined:** Thu Jul 09, 2009 11:14 am **Posts:** 26

Hi Boris,

I added the setdir as indicated and the file is now read. Below is the updated change. The only other issue I have is when the end of file is reached, the variable "result" is set to 1 but it appears the goto instruction is not executing?

if result = 1 goto fclose

The messagebox displays the fact "result" is set to 1 at the end of the file but will not perform the "goto flclose"? The loop just continues and never ends.

I cannot determine why this is?? Where you able to notice this behavior on your end??

Select all

 
setdir 'C:\Documents and Settings\XP User\My Documents\TeraTermScripts'
tmp01 = ''
 
; Open a file.
fileopen fhandle 'test.txt' 0
 
messagebox fhandle 'USER PROMPT 01'
 
:loop
 
; Read a line from the file.
filereadln fhandle line
 
sprintf2 tmp01 'result = %d' result
messagebox tmp01 'USER PROMPT 03'
 
if result = 1 goto fclose
 
; Display the line.
messagebox line 'test.txt'
 
; Repeat until the end of the file.
goto loop
 
:fclose
; Close the file.
fileclose fhandle
 
end 
 

IshmaelCallMe · **Posted:** Thu Jan 21, 2010 7:15 am

If you look in the help file, you see that the sprintf2 command will set the result variable after it executes. This is overwriting the value in result from the filereadln.

dpena · **Joined:** Thu Jul 09, 2009 11:14 am **Posts:** 26

Hi Boris and IshmaelCallMe,

I need to learn to read. I looked up the remarks for sprintf2:

Sprintf2

Quote:

Remarks

As a result of this command, the system variable "result" is set to one of the following values.

Value Status
0 Formatted successfully
1 No format string
2 Invalid format
3 Invalid argument
4 Invalid destnation variable

and as a result created a new variable called "fhandle_result" to preserve the system variable "result" contents. The "if" statement to "goto fclose" now works. I also changed the location of the text file to parse to the "C:\" root directory.

Here is the modified functional code.

Select all

 
setdir 'C:'
 
tmp01 = ''
fhandle_result = 0
 
; Open a file.
fileopen fhandle 'test.txt' 0
 
messagebox fhandle 'USER PROMPT 01'
 
;------
:loop
;------
 
; Read a line from the file.
filereadln fhandle line
fhandle_result = result
 
messagebox line 'USER PROMPT 02'
 
sprintf2 tmp01 'result = %d' fhandle_result
messagebox tmp01 'USER PROMPT 03'
 
if fhandle_result = 1 goto fclose
 
; Display the line.
messagebox line 'test.txt'
 
; Repeat until the end of the file.
goto loop
 
:fclose
; Close the file.
fileclose fhandle
 
end
 

Thank you again for the quick support.

Who is online